FUNCTION WTOT(T,ANE,ID,ILINE)
C     =============================
C
C     Evaluates the total (electron + ion) impact Stark width
C     for four HeI lines
C     After Griem (1974); and Barnard, Cooper, Smith (1974) JQSRT 14,
C     1025 for the 4471 line
C
C     Input: T     - temperature
C            ANE   - electron density
C            ID    - depth index
C            ILINE - index of the line ( = 1  for 4471,
C                                        = 2  for 4387,
C                                        = 3  for 4026,
C                                        = 4  for 4922)
C     Output: WTOT - Stark width in Angstroms
C
      INCLUDE 'PARAMS.FOR'
      INCLUDE 'MODELP.FOR'
      DIMENSION ALPH0(4,4),W0(4,4),ALAM0(4)
      DATA ALPH0 / 0.107, 0.119, 0.134, 0.154,
     *             0.206, 0.235, 0.272, 0.317,
     *             0.172, 0.193, 0.218, 0.249,
     *             0.121, 0.136, 0.157, 0.184/
      DATA W0    / 1.460, 1.269, 1.079, 0.898,
     *             6.130, 5.150, 4.240, 3.450,
     *             4.040, 3.490, 2.960, 2.470,
     *             2.312, 1.963, 1.624, 1.315/
      DATA ALAM0 / 4471.50, 4387.93, 4026.20, 4921.93/
C
      I=JT(ID)
      ALPHA=(TI0(ID)*ALPH0(I,ILINE)+TI1(ID)*ALPH0(I-1,ILINE)+
     *      TI2(ID)*ALPH0(I-2,ILINE))*(ANE*1.E-13)**0.25
      WE=   (TI0(ID)*W0(I,ILINE)+TI1(ID)*W0(I-1,ILINE)+
     *      TI2(ID)*W0(I-2,ILINE))*ANE*1.E-16
      F0=1.884E19/ALAM0(ILINE)/ALAM0(ILINE)
      SIG=(4.32E-5*WE/SQRT(T)*F0/ANE**0.3333)**0.3333
      WTOT=WE*(1.+1.36/SIG*ALPHA**0.8889)
      RETURN
      END