SUBROUTINE ALISK2
C     =================
C
C     Simplified routine ALISET for Kantorovich iteration
C
C     Evaluation of all nexcessary ALI parameters + radiative rates
C     (the routine is analogous to RATES)
C
C
      INCLUDE 'IMPLIC.FOR'
      INCLUDE 'BASICS.FOR'
      INCLUDE 'ATOMIC.FOR'
      INCLUDE 'MODELQ.FOR'
      INCLUDE 'ODFPAR.FOR'
      INCLUDE 'ALIPAR.FOR'
      INCLUDE 'ARRAY1.FOR'
      INCLUDE 'ITERAT.FOR'
      DIMENSION RBNU(MDEPTH)
C     DIMENSION EHKL(MFREQL)
C
C     zero the rates and other quantities 
C
      DO ID=1,ND
         FCOOLI(ID)=0.
         FLFIX(ID)=0.
         FLEXP(ID)=0.
         FPRD(ID)=0.
         FLRD(ID)=0.
         PRADT(ID)=0.
         PRADA(ID)=0.
         DO ITR=1,NTRANS
            RRU(ITR,ID)=0.
            RRD(ITR,ID)=0.
         END DO
      END DO
      PRD0=0.
C
      LROSS=NDRE.LE.0.AND.ITER.EQ.1.OR.LFIN
      IF(HMIX0.GT.0.) LROSS=.TRUE.
      IF(LROSS) THEN
         DO ID=1,ND
            ABROSD(ID)=0.
            SUMDPL(ID)=0.
         END DO
      END IF
C
      DO 100 IJ=1,NFREQ
         IF(IJX(IJ).EQ.-1) GO TO 100
         FR=FREQ(IJ)
         W0=W0E(IJ)
         CALL OPACF1(IJ)
         CALL RTEFR1(IJ)
         CALL ALIFRK(IJ)
         IF(LROSS) CALL ROSSTD(IJ)
         if(ioptab.lt.0) go to 100
         IF(IJEX(IJ).GT.0) THEN
            IJE=IJEX(IJ)
            DO ID=1,ND
               ABSOEX(IJE,ID)=ABSO1(ID)
               EMISEX(IJE,ID)=EMIS1(ID)
               SCATEX(IJE,ID)=SCAT1(ID)
            END DO
         END IF
C             
C        ---------------------
C        Continuum transitions
C        ---------------------
C          
         DO ID=1,ND
            RBNU(ID)=(RAD1(ID)+BNUE(IJ))*EXP(-HKT1(ID)*FR)
            DO 10 IBFT=1,NTRANC
               ITR=ITRBF(IBFT)
               SG=CROSS(IBFT,IJ)
               IF(SG.LE.0.) GO TO 10
               II=ILOW(ITR)
               JJ=IUP(ITR)
               IF(IPZERO(II,ID).NE.0.OR.IPZERO(JJ,ID).NE.0) GO TO 10
               JC=ITRA(JJ,II)
               IF(IFWOP(II).GE.0) THEN
                  ICDW=MCDW(ITR)
                  IF(ICDW.GE.1) SG=SG*DWF1(ICDW,ID)
                ELSE
                  IMER=IMRG(II)
                  SG=SGMG(IMER,ID)
               ENDIF
               SGW0=SG*W0
               RRU(ITR,ID)=RRU(ITR,ID)+SGW0*RAD1(ID)
               RRD(ITR,ID)=RRD(ITR,ID)+SGW0*RBNU(ID)
   10       CONTINUE
         END DO
C            
C        ----------------
C        Line transitions 
C        ----------------
C             
         IF(ISPODF.EQ.0) THEN
         IF(IJLIN(IJ).GT.0) THEN
C
C        the "primary" line at the given frequency
C
            ITR=IJLIN(IJ)
            II=ILOW(ITR)
            JJ=IUP(ITR)
            DO 50 ID=1,ND
               IF(IPZERO(II,ID).NE.0.OR.IPZERO(JJ,ID).NE.0) GO TO 50
               SGW0=PRFLIN(ID,IJ)*W0
               RRU(ITR,ID)=RRU(ITR,ID)+SGW0*RAD1(ID)
               RRD(ITR,ID)=RRD(ITR,ID)+SGW0*RBNU(ID)
   50       CONTINUE
         END IF
         IF(NLINES(IJ).LE.0) GO TO 100
C
C        the "overlapping" lines at the given frequency
C
         DO 90 ILINT=1,NLINES(IJ)
            ITR=ITRLIN(ILINT,IJ)
            if(linexp(itr)) go to 90
            II=ILOW(ITR)
            JJ=IUP(ITR)
            IJ0=IFR0(ITR)
            DO IJT=IJ0,IFR1(ITR)
               IF(FREQ(IJT).LE.FR) THEN
                  IJ0=IJT
                  GO TO 70
               END IF
            END DO
   70       IJ1=IJ0-1
            A1=(FR-FREQ(IJ0))/(FREQ(IJ1)-FREQ(IJ0))*W0
            A2=W0-A1
            DO 80 ID=1,ND
               IF(IPZERO(II,ID).NE.0.OR.IPZERO(JJ,ID).NE.0) GO TO 80
               SGW0=A1*PRFLIN(ID,IJ1)+A2*PRFLIN(ID,IJ0)
               RRU(ITR,ID)=RRU(ITR,ID)+SGW0*RAD1(ID)
               RRD(ITR,ID)=RRD(ITR,ID)+SGW0*RBNU(ID)
   80       CONTINUE
   90    CONTINUE
C
C        Opacity sampling option
C
         ELSE
         IF(NLINES(IJ).LE.0) GO TO 100
         DO 190 ILINT=1,NLINES(IJ)
            ITR=ITRLIN(ILINT,IJ)
            KJ=IJ-IFR0(ITR)+KFR0(ITR)
            INDXPA=IABS(INDEXP(ITR))
            II=ILOW(ITR)
            JJ=IUP(ITR)
            IF(INDXPA.NE.3 .AND. INDXPA.NE.4) THEN
               DO 150 ID=1,ND
                  IF(IPZERO(II,ID).NE.0.OR.IPZERO(JJ,ID).NE.0) GO TO 150
                  SGW0=PRFLIN(ID,KJ)*W0
                  RRU(ITR,ID)=RRU(ITR,ID)+SGW0*RAD1(ID)
                  RRD(ITR,ID)=RRD(ITR,ID)+SGW0*RBNU(ID)
  150          CONTINUE
             ELSE
                DO 160 ID=1,ND
                   IF(IPZERO(II,ID).NE.0.OR.
     *                IPZERO(JJ,ID).NE.0) GO TO 160
                   KJD=JIDI(ID)
                   SG=EXP(XJID(ID)*SIGFE(KJD,KJ)+(UN-XJID(ID))*
     *             SIGFE(KJD+1,KJ))
                   SGW0=SG*W0
                   RRU(ITR,ID)=RRU(ITR,ID)+SGW0*RAD1(ID)
                   RRD(ITR,ID)=RRD(ITR,ID)+SGW0*RBNU(ID)
  160           CONTINUE
            END IF
  190    CONTINUE
         END IF
  100 CONTINUE
C      
C     multiply some quantities by frequency-independent constants
C
      DO ID=1,ND
         FCO OL(ID)=REINT(ID)*FCOOLI(ID)-REDIF(ID)*FLFIX(ID)
         IF(CRSW(ID).NE.UN) THEN
            DO ITR=1,NTRANS
               RRU(ITR,ID)=RRU(ITR,ID)*CRSW(ID)
               RRD(ITR,ID)=RRD(ITR,ID)*CRSW(ID)
            END DO
         END IF
      END DO
C
C     radiation pressure
C
      PRDX=1.
      DO ID=1,ND
         PRADT(ID)=PRADT(ID)*PCK
         PRADA(ID)=PRADA(ID)*PCK
         if(prada(id).gt.0.) PRDR=PRADT(ID)/PRADA(ID)
         IF(PRDR.LT.PRDX) PRDX=PRDR
      END DO
      PRD0=PRD0/DENS1(1)*DM(1)*PCK
      IF(LFIN) WRITE(10,1100) PRDX,ITER
 1100 FORMAT(' PRAD MIN RATIO ',F10.6,I4)
C
C     Rosseland mean opacity
C
      IF(LROSS) THEN
         DO ID=1,ND
            ABROSD(ID)=SUMDPL(ID)/(ABROSD(ID)*DENS(ID))
         END DO
      END IF
      RETURN
      END