SUBROUTINE PZEVAL
C     =================
C
C     Auxiliary procedure called from RESOLV
C     determination of the total and gas pressures, and logarithmic
C     gradient of pressure
C
      INCLUDE 'IMPLIC.FOR'
      INCLUDE 'BASICS.FOR'
      INCLUDE 'MODELQ.FOR'
      INCLUDE 'ALIPAR.FOR'
      common/icnrsp/iconrs
C
C     total pressure, gas pressure, and logarithmic gradient DELTA
C
      IF(IPPZEV.GT.0) WRITE(6,601)
      DO ID=1,ND
         PTURB=HALF*DENS(ID)*VTURB(ID)*VTURB(ID)
         PGS0=(DENS(ID)/WMM(ID)+ELEC(ID))*BOLK*TEMP(ID)
         PTOTL0=PGS0+PRADT(ID)+PTURB
         PTOTL1=GRAV*DM(ID)+PRADT(1)-PRD0
         PGS1=PTOTL1-PTURB-PRADT(ID)
         AAA=3.D0*PRADT(ID)/TEMP(ID)**4/7.5639D-15
         if(idisk.eq.0) then
            PTOTAL(ID)=PTOTL1
            PGS(ID)=PGS1
          else
            PTOTAL(ID)=PTOTL0
            PGS(ID)=PGS0
         end if
         IF(IPPZEV.GT.0) WRITE(6,602) ID,PTOTL0,PTOTL1,PGS0,PGS1,
     *                   PRADT(ID),AAA
      END DO
      IF(HMIX0.LT.0.) RETURN
      IF(IPPZEV.GT.0) THEN
         WRITE(6,600) ITER-1
         CALL CONOUT(1,IPCONF)
      END IF
      if(iconre.gt.0.and.iter.le.iconre.and.iter.ge.iconrs) call conref
      IF(IPPZEV.EQ.0.AND.LFIN) THEN
          WRITE(6,600) ITER-1
          CALL CONOUT(1,1)
      END IF
  600 FORMAT(/' CONVECTIVE FLUX: RESOLV; GLOBAL ITERATION =',I2/)
  601 FORMAT(/'  ID   PTOT-SUM  PTOT-MG   PGAS-RHO  PGAS-P    PRAD',
     *       '       A'/)
  602 FORMAT(I4,1P6D10.3)
      RETURN
      END